Aplicación de la lógica para un propósito comercial personalizado

Aplicar después del evento de cambio con la siguiente funcionalidad de valor establecido:

• Establecer el campo clave ID si todavía es inicial.

  Consejo: Cambiar parámetro bonusplan le permite leer y cambiar los datos del nodo actual.

  Consejo: Puede leer los detalles existentes sobre el Plan de bonificación a través de la Vista de CDS designada como Identificador de propósito comercial (aquí: YY1_BONUSPLAN).

  Consejo: Con la combinación de teclas CTRL + espacio Puedes acceder a la cumplimentación del código es muy útil.

  

  * set ID
  IF bonusplan-id IS INITIAL.
     SELECT MAX( id ) FROM yy1_bonusplan INTO @DATA(current_max_id).
     bonusplan-id = current_max_id + 1.
  ENDIF.
  

• Establezca la unidad de medida para los porcentajes de bonificación en P1 que es el código para% (porcentaje)

  * set percentage unit
  bonusplan-lowbonuspercentage_u = bonusplan-highbonuspercentage_u = 'P1'.
  

• Determinar y determinar el nombre del empleado a partir de la identidad del empleado

  Consejo: Helper ofrece una clase expansiva CL_ABAP_CONTEXT_INFO por método GET_USER_FORMATTED_NAME que requiere una identificación de usuario para restaurar su nombre formateado

  * set Employee Name
  IF bonusplan-employeeid IS NOT INITIAL.
     bonusplan-employeename = cl_abap_context_info=>get_user_formatted_name( bonusplan-employeeid ).
  ENDIF.
  

Dependiendo de las siguientes comprobaciones, configure el isconsistent propiedad.

• Mira eso ValidityStartDate y ValidityEndDate set y eso ValidityStartDate antes en el tiempo que ValidityEndDate.
• Verifique que los factores y porcentajes estén configurados correctamente (todos> 0, porcentajes <100, LowBonusAssignmentFactor < HighBonusAssignmentFactor)
• Verifique que la ID de empleado esté configurada

* consistency check START
IF bonusplan-validitystartdate IS INITIAL
 OR bonusplan-validityenddate IS INITIAL
 OR bonusplan-validitystartdate GE bonusplan-validityenddate
 OR bonusplan-lowbonusassignmentfactor IS INITIAL
 OR bonusplan-highbonusassignmentfactor IS INITIAL
 OR bonusplan-lowbonuspercentage_v IS INITIAL
 OR bonusplan-highbonuspercentage_v IS INITIAL
 OR bonusplan-lowbonuspercentage_v GE 100
 OR bonusplan-highbonuspercentage_v GE 100
 OR bonusplan-lowbonusassignmentfactor GE bonusplan-highbonusassignmentfactor
 OR bonusplan-employeeid IS INITIAL.
    bonusplan-isconsistent = abap_false.
ELSE.
    bonusplan-isconsistent = abap_true.
ENDIF.
* consistency check END

1. Si está en la lógica de After Modification, puede acceder a Before Save Logic de esta manera:

   • Regresar en la aplicación
   • En la pestaña «Lógica», vaya a la sección «Decisión y validación»

2. Implementación Antes de guardar el evento con la siguiente funcionalidad

   • Si el plan de bonificación es consistente, los ahorros pueden continuar, si no se ahorran. Para guardar no se requiere ningún procesamiento adicional y la lógica puede omitirse.

     Consejo: La configuración del parámetro de exportación válido debe ser verdadera para guardar y falsa solo para rechazo

     * decide about save rejection
     IF bonusplan-isconsistent EQ abap_true.
         valid = abap_true.
         RETURN.
     ELSE.
         valid = abap_false.
     ENDIF.
     

   • Si el plan de bonificación no es consistente, escriba el primer error encontrado en el mensaje y detenga el procesamiento lógico.
     Aquí están los posibles errores en detalle:

     • ValidityStartDate y ValidityEndDate Debe ser arreglado
     • ValidityStartDate debe ser antes en el tiempo que ValidityEndDate
     • Los factores y porcentajes deben ser> 0
     • Los porcentajes deben ser <100
     • Debe ser LowBonusAssignFactor
     • Se debe establecer la identificación del empleado

     * consistency error message START
     IF bonusplan-validitystartdate IS INITIAL OR bonusplan-validityenddate IS INITIAL.
         message = 'Validity Period must not be empty.'.
         RETURN.
     ELSEIF bonusplan-validitystartdate GE bonusplan-validityenddate.
         CONCATENATE 'Validity End Date' bonusplan-validityenddate 'must be later than Validity Start Date' bonusplan-validitystartdate '!' INTO message SEPARATED BY space.
         RETURN.
     ENDIF.
     
     IF bonusplan-targetamount_v IS INITIAL.
         message = 'Target Amount must be over 0!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-targetamount_c IS INITIAL.
         message = 'Target Amount Currency must be set!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-lowbonusassignmentfactor IS INITIAL
      OR bonusplan-highbonusassignmentfactor IS INITIAL.
         message = 'Assignment Factors must be over 0!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-lowbonuspercentage_v IS INITIAL
      OR bonusplan-highbonuspercentage_v IS INITIAL.
         message = 'Percentages must be over 0!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-lowbonuspercentage_v GE 100
      OR bonusplan-highbonuspercentage_v GE 100.
         message = 'Percentage must be below 100!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-lowbonusassignmentfactor GE bonusplan-highbonusassignmentfactor.
         message = 'Low Bonus Factor must be smaller than High Bonus Factor!'.
         RETURN.
     ENDIF.
     
     IF bonusplan-employeeid IS INITIAL.
         message = 'Employee ID must be set!'.
         RETURN.
     ENDIF.
     * consistency error message  END
     

3. Publicación la lógica antes de guardar